weather-station/Arduino/outdoor-weather-station/99_main.ino

void setup() {
#ifdef USE_SERIAL
	Serial.begin(115200);
	delay(500);
#endif

	wakeTime = millis();
	debug("Wake time: %d", wakeTime);

	initLeds(); // Shows errors, so needs to be first
	
	initHumidity();
	initPressure();
}

void loop() {
	debug("----------------------");
	updateHumidity();
	updatePressure();
	
	uint16_t light = analogRead(LIGHT_PIN);

	debug("Light value:            %d", light);
	debug("Humidity - Humidity:    %f", HumTemp.humidity);
	debug("Humidity - Temperature: %f", HumTemp.temperature);
	debug("Pressure - Temperature: %f", PressTemp.temperature);
	debug("Pressure - Pressure:    %f", PressTemp.pressure);

	float averageTemperature = (HumTemp.temperature + PressTemp.temperature) / 2;
	debug("Average - Temperature:  %f", averageTemperature);

	debug("=====");
	
	initWifi();

#ifdef TEST_MODE
	getSomething();
	hideProgress();
	delay(5000);
	deepSleep();
#else
	boolean complete = false;
	while(!complete) {
		delay(500);
		debug("Uploading data");
		complete = uploadData(
				averageTemperature,
				PressTemp.pressure,
				HumTemp.humidity,
				light
			);
	}

	hideProgress();

	delay(1000);
	deepSleep();
#endif
}